The following example file shows how to set up a polypeptide segment (Tyr, Ala, Glu, Lys, Ile, Ala), assuming that the topology and parameters have been previously read. For completeness, the definitions of the patch residues PEPT, PROP, NTER, and CTER have been included. Normally, these patch residues are already defined in the topology files.
topology
PRESidue PEPT
ADD BOND -C +N
ADD ANGLE -CA -C +N
ADD ANGLE -O -C +N
ADD ANGLE -C +N +CA
ADD ANGLE -C +N +H
ADD DIHEdral -C +N +CA +C
ADD DIHEdral -N -CA -C +N
ADD DIHEdral -CA -C +N +CA
ADD IMPRoper -C -CA +N -O {planar -C}
ADD IMPRoper +N -C +CA +H {planar +N}
END
PRESidue PEPP
ADD BOND -C +N
ADD ANGLE -CA -C +N
ADD ANGLE -O -C +N
ADD ANGLE -C +N +CA
ADD ANGLE -C +N +CD
ADD DIHEdral -C +N +CA +C
ADD DIHEdral -N -CA -C +N
ADD DIHEdral -CA -C +N +CA
ADD IMPRoper -C -CA +N -O {planar -C}
ADD IMPRoper +N +CA +CD -C {planar +N}
END
PRESidue NTER
GROUp
ADD ATOM +HT1 TYPE=HC CHARge=0.35 END
ADD ATOM +HT2 TYPE=HC CHARge=0.35 END
MODIfy ATOM +N TYPE=NH3 CHARge=-0.30 END
ADD ATOM +HT3 TYPE=HC CHARge=0.35 END
DELETE ATOM +H END
MODIfy ATOM +CA CHARge=0.25 END
ADD BOND +HT1 +N
ADD BOND +HT2 +N
ADD BOND +HT3 +N
ADD ANGLe +HT1 +N +HT2
ADD ANGLe +HT2 +N +HT3
ADD ANGLe +HT2 +N +CA
ADD ANGLe +HT1 +N +HT3
ADD ANGLe +HT1 +N +CA
ADD ANGLe +HT3 +N +CA
ADD DIHEdral +HT2 +N +CA +C
ADD DIHEdral +HT1 +N +CA +C
ADD DIHEdral +HT3 +N +CA +C
ADD DONOr +HT1 +N
ADD DONOr +HT2 +N
ADD DONOr +HT3 +N
END
PRESidue PROP
GROUp
ADD ATOM +HT1 TYPE=HC CHARge= 0.35 END
ADD ATOM +HT2 TYPE=HC CHARge= 0.35 END
MODIfy ATOM +N TYPE=NH3 CHARge=-0.20 END
MODIfy ATOM +CD CHARge= 0.25 END
MODIfy ATOM +CA CHARge= 0.25 END
ADD BOND +HT1 +N
ADD BOND +HT2 +N
ADD ANGLe +HT1 +N +HT2
ADD ANGLe +HT2 +N +CA
ADD ANGLe +HT1 +N +CD
ADD ANGLe +HT1 +N +CA
ADD ANGLe +CD +N +HT2
ADD DIHEdral +HT2 +N +CA +C
ADD DIHEdral +HT1 +N +CA +C
ADD DONOr +HT1 +N
ADD DONOr +HT2 +N
END
PRESidue CTER
GROUp
MODIfy ATOM -C CHARge= 0.14 END
ADD ATOM -OT1 TYPE=OC CHARge=-0.57 END
ADD ATOM -OT2 TYPE=OC CHARge=-0.57 END
DELETE ATOM -O END
ADD BOND -C -OT1
ADD BOND -C -OT2
ADD ANGLe -CA -C -OT1
ADD ANGLe -CA -C -OT2
ADD ANGLe -OT1 -C -OT2
ADD DIHEdral -N -CA -C -OT2
ADD IMPRoper -C -CA -OT2 -OT1
ADD ACCEptor -OT1 -C
ADD ACCEptor -OT2 -C
END
end
segment
name="PROT"
chain
link pept head - * tail + * end
first prop tail + pro end ! special n-ter for PRO
first nter tail + * end
last cter head - * end
sequence TYR ALA GLU LYS ILE ALA end
end
end
The information about the patch residues is normally included
in the topology file. The information about the peptide
linkages is also included in the ``toph19.pep" file in the
``toppar" directory.
Wildcards allow one to use the same patch residues
(``PEPT") for all combinations of amino acids. The only exception
is Pro, which needs a special N-terminal patch.
The residues are numbered
consecutively, starting with 1. To use a particular
numbering for residues, one should use
the COOR option to read the sequence from the coordinate file.